Adding Example4: MAX17048 Kitchen Sink

Author: PaulZC

examples/Example4_MAX17048_KitchenSink/Example4_MAX17048_KitchenSink.ino

@@ -0,0 +1,181 @@
+/******************************************************************************
+Example4: test all the things on the MAX17048
+By: Paul Clark, SparkFun Electronics
+Date: October 23rd 2020
+
+This example is an everything-but-the-kitchen-sink test of the MAX17048.
+
+This code is released under the MIT license.
+
+Distributed as-is; no warranty is given.
+******************************************************************************/
+
+#include <Wire.h> // Needed for I2C
+
+#include <SparkFun_MAX1704x_Fuel_Gauge_Arduino_Library.h> // Click here to get the library: http://librarymanager/All#SparkFun_MAX1704x_Fuel_Gauge_Arduino_Library
+
+SFE_MAX1704X lipo(MAX1704X_MAX17048); // Create a MAX17048
+
+void setup()
+{
+	Serial.begin(115200); // Start serial, to output debug data
+  while (!Serial)
+    ; //Wait for user to open terminal
+  Serial.println(F("MAX17048 Example"));
+
+  Wire.begin();
+
+  lipo.enableDebugging(); // Uncomment this line to enable helpful debug messages on Serial
+
+  // Set up the MAX17048 LiPo fuel gauge:
+  if (lipo.begin() == false) // Connect to the MAX17048 using the default wire port
+  {
+    Serial.println(F("MAX17048 not detected. Please check wiring. Freezing."));
+    while (1)
+      ;
+  }
+
+  // Just because we can, let's reset the MAX17048
+  Serial.println(F("Resetting the MAX17048..."));
+  delay(1000); // Give it time to get its act back together
+
+  // Read and print the reset indicator
+  Serial.print(F("Reset Indicator was: "));
+  bool RI = lipo.isReset(true); // Read the RI flag and clear it automatically if it is set
+  Serial.println(RI); // Print the RI
+  // If RI was set, check it is now clear
+  if (RI)
+  {
+    Serial.print(F("Reset Indicator is now: "));
+    RI = lipo.isReset(); // Read the RI flag
+    Serial.println(RI); // Print the RI    
+  }
+
+  // To quick-start or not to quick-start? That is the question!
+  // Read the following and then decide if you do want to quick-start the fuel gauge.
+  // "Most systems should not use quick-start because the ICs handle most startup problems transparently,
+  //  such as intermittent battery-terminal connection during insertion. If battery voltage stabilizes
+  //  faster than 17ms then do not use quick-start. The quick-start command restarts fuel-gauge calculations
+  //  in the same manner as initial power-up of the IC. If the system power-up sequence is so noisy that the
+  //  initial estimate of SOC has unacceptable error, the system microcontroller might be able to reduce the
+  //  error by using quick-start."
+  // If you still want to try a quick-start then uncomment the next line:
+	//lipo.quickStart();
+
+  // Read and print the device ID
+  Serial.print(F("Device ID: 0x"));
+  uint8_t id = lipo.getID(); // Read the device ID
+  if (id < 0x10) Serial.print(F("0")); // Print the leading zero if required
+  Serial.println(id, HEX); // Print the ID as hexadecimal
+
+  // Read and print the device version
+  Serial.print(F("Device version: 0x"));
+  uint8_t ver = lipo.getVersion(); // Read the device version
+  if (ver < 0x10) Serial.print(F("0")); // Print the leading zero if required
+  Serial.println(ver, HEX); // Print the version as hexadecimal
+
+  // Read and print the battery threshold
+  Serial.print(F("Battery empty threshold is currently: "));
+  Serial.print(lipo.getThreshold());
+  Serial.println(F("%"));
+
+	// We can set an interrupt to alert when the battery SoC gets too low.
+	// We can alert at anywhere between 1% and 32%:
+	lipo.setThreshold(20); // Set alert threshold to 20%.
+
+  // Read and print the battery empty threshold
+  Serial.print(F("Battery empty threshold is now: "));
+  Serial.print(lipo.getThreshold());
+  Serial.println(F("%"));
+
+  // Read and print the high voltage threshold
+  Serial.print(F("High voltage threshold is currently: "));
+  float highVoltage = ((float)lipo.getVALRTMax()) * 0.02; // 1 LSb is 20mV. Convert to Volts.
+  Serial.print(highVoltage, 2);
+  Serial.println(F("V"));
+
+  // Set the high voltage threshold
+  lipo.setVALRTMax((float)4.1); // Set high voltage threshold (Volts)
+
+  // Read and print the high voltage threshold
+  Serial.print(F("High voltage threshold is now: "));
+  highVoltage = ((float)lipo.getVALRTMax()) * 0.02; // 1 LSb is 20mV. Convert to Volts.
+  Serial.print(highVoltage, 2);
+  Serial.println(F("V"));
+
+  // Read and print the low voltage threshold
+  Serial.print(F("Low voltage threshold is currently: "));
+  float lowVoltage = ((float)lipo.getVALRTMin()) * 0.02; // 1 LSb is 20mV. Convert to Volts.
+  Serial.print(lowVoltage, 2);
+  Serial.println(F("V"));
+
+  // Set the low voltage threshold
+  lipo.setVALRTMin((float)3.9); // Set low voltage threshold (Volts)
+
+  // Read and print the low voltage threshold
+  Serial.print(F("Low voltage threshold is now: "));
+  lowVoltage = ((float)lipo.getVALRTMin()) * 0.02; // 1 LSb is 20mV. Convert to Volts.
+  Serial.print(lowVoltage, 2);
+  Serial.println(F("V"));
+
+  // Enable the State Of Change alert
+  Serial.print(F("Enabling the 1% State Of Change alert: "));
+  if (lipo.enableSOCAlert())
+  {
+    Serial.println(F("success."));
+  }
+  else
+  {
+    Serial.println(F("FAILED!"));
+  }
+  
+  // Read and print the HIBRT Active Threshold
+  Serial.print(F("Hibernate active threshold is: "));
+  float actThr = ((float)lipo.getHIBRTActThr()) * 0.00125; // 1 LSb is 1.25mV. Convert to Volts.
+  Serial.print(actThr, 5);
+  Serial.println(F("V"));
+
+  // Read and print the HIBRT Hibernate Threshold
+  Serial.print(F("Hibernate hibernate threshold is: "));
+  float hibThr = ((float)lipo.getHIBRTHibThr()) * 0.208; // 1 LSb is 0.208%/hr. Convert to %/hr.
+  Serial.print(hibThr, 3);
+  Serial.println(F("%/h"));
+}
+
+void loop()
+{
+  // Print the variables:
+  Serial.print("Voltage: ");
+  Serial.print(lipo.getVoltage());  // Print the battery voltage
+  Serial.print("V");
+
+  Serial.print(" Percentage: ");
+  Serial.print(lipo.getSOC(), 2); // Print the battery state of charge with 2 decimal places
+  Serial.print("%");
+
+  Serial.print(" Change Rate: ");
+  Serial.print(lipo.getChangeRate(), 2); // Print the battery change rate with 2 decimal places
+  Serial.print("%/hr");
+
+  Serial.print(" Alert: ");
+  Serial.print(lipo.getAlert()); // Print the generic alert flag
+
+  Serial.print(" Voltage High Alert: ");
+  Serial.println(lipo.isVoltageHigh()); // Print the alert flag
+
+  Serial.print(" Voltage Low Alert: ");
+  Serial.println(lipo.isVoltageLow()); // Print the alert flag
+
+  Serial.print(" Empty Alert: ");
+  Serial.print(lipo.isLow()); // Print the alert flag
+
+  Serial.print(" SOC 1% Change Alert: ");
+  Serial.print(lipo.isChange()); // Print the alert flag
+  
+  Serial.print(" Hibernating: ");
+  Serial.print(lipo.isHibernating()); // Print the alert flag
+  
+  Serial.println();
+
+  delay(500);
+}

src/SparkFun_MAX1704x_Fuel_Gauge_Arduino_Library.h

@@ -260,8 +260,8 @@ class SFE_MAX1704X
   // INPUT: [clear] - If [clear] is true, the alert flag will be cleared if it
   // was set.
   bool isReset(bool clear = false);       //True after POR
-  bool isVoltageHigh(bool clear = false); //True when VCELL is above VALRTMAX (see setAlertMinVoltage)
-  bool isVoltageLow(bool clear = false);
+  bool isVoltageHigh(bool clear = false); //True when VCELL goes above VALRTMAX (see setVALRTMax)
+  bool isVoltageLow(bool clear = false); //True when VCELL goes below VALRTMIN (see setVALRTMin)
   bool isVoltageReset(bool clear = false);
   bool isLow(bool clear = false);    //True when SOC crosses the value in ATHD (see setThreshold)
   bool isChange(bool clear = false); //True when SOC changes by at least 1% and SOCAlert is enabled