Ecto type for Timex.Duration?

[Fire-Dragon-DoL]

Hello,
Is possible to use Timex.Duration (or some Timex.Duration.Ecto) as type for an Ecto field?

The purpose is to store, for example, a delay of something. E.g. "do not use this account for 3 weeks" in a ban-like system.

In an ideal world, it would encode to postgres interval type too.
Is there any chance this is supported?

[markquezada]

@Fire-Dragon-DoL Did you ever figure out a way to do this?

[Fire-Dragon-DoL]

I do not, sorry, I haven't worked with Elixir in a while.

[Wigny]

Looking for something similar, I've come up with a custom Ecto type that seems to be working:

defmodule MyApp.Type.Duration do
  use Ecto.Type

  alias Timex.Duration
  alias Postgrex.Interval

  defguardp is_duration(value) when is_struct(value, Duration)
  defguardp is_interval(value) when is_struct(value, Interval)

  @impl true
  def type, do: :interval

  @impl true
  def cast(value) when is_duration(value), do: {:ok, value}
  def cast(value) when is_interval(value), do: {:ok, from_interval(value)}
  def cast(_value), do: :error

  @impl true
  def load(value) when is_interval(value), do: {:ok, from_interval(value)}

  @impl true
  def dump(value) when is_duration(value), do: {:ok, to_interval(value)}
  def dump(_value), do: :error

  defp from_interval(interval) do
    interval.microsecs
    |> Duration.from_microseconds()
    |> Duration.add(Duration.from_seconds(interval.secs))
    |> Duration.add(Duration.from_days(interval.days))
    |> Duration.add(Duration.from_weeks(interval.months * 4))
  end

  defp to_interval(duration) do
    microseconds = Duration.to_microseconds(duration)

    %Interval{microsecs: microseconds}
  end
end